动画效果：

好，现在我们就开始至做这个效果。

　　第一步，我们先来建立一个graphic，在这个graphic里我们要画出被鼠标吸引的按钮的外观。我们的做法是使用多层绘制，单层合并的方法。做一个“◎”的矢量图。大小15*15

　　第二步，我们建立一个button,把graphic拖入button,在up,over,down调节一下Alpha值，使按钮在不同情况下，有不同的显示。在hit桢加上15*15的热区。

　　第三步，我们在建立一个Movie Clip,把button拖入，放置在(0,0)中心点要对齐。这一步的目的在于：button是不能设定Instance Name的，所以一般的我们要想对按钮进行AS控制时都要把按钮放入MC中设定Instance Name.

　　第四步，我们把MC拖入Scene 1里，并在Instance浮动面板里设定他的Instance Name为button.

　　好，到这我们就已经完成准备工作,(初值的设定和元件的制作)。

　　第五步，我们对关键桢添加AS(Scene 1,第一桢)，双击打开Action面版，在桢上我们添加的AS目的是为了把MC随机复制到Scene的舞台里。
   
　　AS如下：

　　for (i=0; i<30; i++) {
　　duplicateMovieClip ("button", "button"+i, i);
　　_root["button"+i]._x = random(300)+150;
　　_root["button"+i]._y = random(300)+150;
　　}

　　这里我们使用的是一个for语句来执行循环，i的值从0到30，通过duplicateMovieClip()可以复制出31个MC.

　　_root["button"+i]._x的含义：假设i=5,_root["button"+5]._x等价于_root.button5._x,这样写可以在循环里动态的给_x属性赋值。

　　random(300),因为我们的movie是600*600所以设为300，取的是1~300的随机数，加上150就可以把复制出的MC集中在舞台中间。

　　第六步，我们选择MC,在MC上添加AS.

　　AS如下：

　　onClipEvent (load) {
　　physics = [.9, 0.75];
　　start_x = this._x;
　　start_y = this._y;
　　}
　　onClipEvent (enterFrame) {
　　dis_x = _root._xmouse - start_x;
　　dis_y = _root._ymouse - start_y;
　　if ((dis_x * dis_x) + (dis_y * dis_y) < 2500) {
　　target_x = _root._xmouse;
　　target_y = _root._ymouse;
　　} else {
　　target_x = start_x;
　　target_y = start_y;
　　}
　　xspeed = ((target_x - this._x)*physics[0])+(xspeed*physics[1]);
　　this._x += xspeed;
　　yspeed = ((target_y - this._y)*physics[0])+(yspeed*physics[1]);
　　this._y += yspeed;
　　}

　　this的含义就是指当前的MC，涉及到的属性也都是当前MC的属性。

　　第二部分，onClipEvent(enterframe){},我们要求出鼠标和MC的绝对距离，所以我们需要一个平方和求绝对距离作为if语句的条件。这样我们就利用if语句实现了鼠标吸引的初步效果，当然我使用的是新变量，还没有和MC建立联系。

　　最后的xspeed = ((target_x - this._x)*physics[0])+(xspeed*physics[1]);语句目的在于MC被鼠标吸引时出现缓冲的效果。这里使用了一个表达式循环，第一次执行时xspeed没有值赋于，所以(xspeed*physics[1]);为0，随着语句的执行配合this._x += xspeed;语句使x坐标越来越接近鼠标位置的x坐标，从而实现了缓冲的效果。

（出处：网侠）